Back to the Top
Hello,
I am trying to simultaneously model the PK of a drug and its
metabolite using NONMEM. I have plasma observations for the parent
compound (17-AAG) and the metabolite (17-AG). I also have 24hr urine
collection data for both compounds. When I tried to model this using
ADVAN7 in NONMEM, it stops almost immediately with the following error:
MONITORING OF SEARCH:
0PRED EXIT CODE = 1
0INDIVIDUAL NO. 1 ID=0.10100000E+03 (WITHIN-INDIVIDUAL) DATA
REC NO. 4
THETA=
1.43E+04 2.42E+04 8.44E+04 8.96E+04 1.24E+04 2.13E+04
5.00E+04
NUMERICAL DIFFICULTIES OBTAINING THE SOLUTION.
THE COEFFICIENT MATRIX IS ALGORITHMICALLY SINGULAR.
0PROGRAM TERMINATED BY OBJ
MESSAGE ISSUED FROM ESTIMATION STEP
AT INITIAL OBJ. FUNCTION EVALUATION
1THERE ARE ERROR MESSAGES IN FILE PRDERR
2006.11.20.1820.57
Here is the NONMEM control stream that I am using:
$INPUT ID AMT EVID RATE TIME DV UVOL CMT BW BSA SEX AGE CRCL BR AP
AST DOSE
$DATA ..\data.dta IGNORE=#
$SUBROUTINE ADVAN7
$MODEL
COMP=(CENTRAL, DEFDOSE, DEFOBS)
COMP=PERIPH
COMP=METAB
COMP=("URINE", NODOSE, INITIALOFF)
COMP=("METABUR", NODOSE, INITIALOFF)
$PK
TVCL = THETA(1)
CL = TVCL*EXP(ETA(1))
TVV = THETA(2)
V = TVV * EXP(ETA(2))
K14 = CL/V
S1 = V
TVQ = THETA(3)
Q = TVQ * EXP(ETA(3))
TVV2 = THETA(4)
V2 = TVV2 * EXP(ETA(4))
K12 = Q/V
K21 = Q/V2
TVCLM = THETA(5)
CLM = TVCLM * EXP(ETA(5))
K13 = CLM/V
TVCLMO = THETA(6)
CLMO = TVCLMO * EXP(ETA(6))
TVV3 = THETA(7)
V3 = TVV3 * EXP(ETA(7))
K35 = CLMO/V3
S3 = V3
S0=UVOL
$ERROR
ASY1=0
IF (CMT.EQ.1) ASY1=1
ASY2=0
IF (CMT.EQ.3) ASY2=1
ASY3=0
IF (CMT.EQ.4) ASY3=1
IPRED = F
W = 1
IF (F.EQ.0) W=1
IRES = DV-IPRED
IWRES = IRES/W
Y=IPRED+ASY1*ERR(1)+ASY2*ERR(2)+ASY3*ERR(3)+(1-ASY1)*(1-ASY2)*(1-
ASY3)*ERR(4)
$THETA (0,14300.,) ; TVCL
$THETA (0,24200.,) ; TVV
$THETA (0,84400.,) ; TVQ
$THETA (0,89600.,) ; TVV2
$THETA (0,12400.,) ; TVCLM
$THETA (0,21300.,) ; TVCLMO
$THETA (0,50000.,) ; TVV3
$OMEGA 0.25 ; ETATVCL
$OMEGA 0.25 ; ETATVV
$OMEGA 0.25 ; ETATVQ
$OMEGA 0.25 ; ETATVV2
$OMEGA 0.25 ; ETATVCLM
$OMEGA 0.25 ; ETATVCLMO
$OMEGA 0.25 ; ETATVV3
$SIGMA 100 ; ERRSD17AAG
$SIGMA 100 ; ERRSD17AG
$SIGMA 100 ; ERRSD17AAG URINE
$SIGMA 100 ; ERRSD17AG URINE
$EST METH=0 MAXEVAL=9999 NOABORT POSTHOC PRINT=5 SIGDIGITS=5
$COVARIANCE
The data file looks like this:
#ID AMT EVID RATE TIME DV UVOL CMT
101 31500000 1 31500000 0 0
0 1
101 0 2 0 0 0 0 4
101 0 2 0 0 0 0 5
101 0 0 0 0.5 20 0 3
101 0 0 0 0.5 231 0 1
101 0 0 0 0.92 51 0 3
101 0 0 0 0.92 300 0 1
101 0 0 0 1.08 47 0 3
101 0 0 0 1.08 146 0 1
101 0 0 0 1.25 40 0 3
101 0 0 0 1.25 109 0 1
101 0 0 0 1.5 55 0 3
101 0 0 0 1.5 121 0 1
101 0 0 0 2 42 0 3
101 0 0 0 2 119 0 1
101 0 0 0 3 25 0 3
101 0 0 0 3 75 0 1
101 0 0 0 5 17 0 3
101 0 0 0 5 25 0 1
101 0 0 0 9 0 0 1
101 0 0 0 9 0 0 3
101 0 0 0 17 0 0 1
101 0 0 0 17 0 0 3
101 0 0 0 24 1993.956 904 -4
101 0 0 0 24 609.6032 904 -5
I was able to model the above data without urine observations, so I
feel there must be something wrong with the way I am coding the urine
compartments. I would really appreciate any advice.
Thanks,
Tarek A. Leil, Ph.D.
Department of Oncology, Guggenheim 1311
Mayo Clinic
200 First Street SW
Rochester, MN 55905
ph: 507-538-4227
fax: 507-266-5146
Back to the Top
Dear Tarek,
I would suggest replacing:
S0 = UVOL
by
S4 = UVOL
S5 = UVOL
in you NONMEM code. S0 is the output scaling parameter (compartment 0
or 6) and you are observing urine in compartment 4 and 5 for parent and
metabolite, respectively.
I hope this help!
Jean
PharmPK Discussion List Archive Index page
Copyright 1995-2010 David W. A. Bourne (david@boomer.org)