PharmPK Discussion - Enterohepatic circulation using phoenix

• On 14 Aug 2011 at 17:26:38, zhu tou (zhutoug888.-at-.gmail.com) sent the message
  

  
  Hi all,
  
  Recently I am trying to develop a pk model with enterohepatic circulation using Phoenix. I
  spent a lot of time trying to write code for " bile empty" in Phoenix with no success.
  
  Please help if you have suggestions.
  
  Thanks!
  
  Zhu
  

  Back to the Top

• On 16 Aug 2011 at 12:29:40, Emily Colby (Emily.Colby.aaa.certara.com) sent the message
  

  
  The following message was posted to: PharmPK
  
  Dear Zhu,
  
  Here is the PML code for PK40, enterohepatic recirculation.
  
  test(){
         Tbeginbump = 10
         deriv(A1 = Ka*Ag - Cl*C - Cld*(C-Ct) - K1g*C*Vc)
         deriv(A2 = Cld*(C-Ct))
         deriv(Abile = K1g*C*Vc - Gbr*Abile/Tau)
         deriv(Ag = Gbr*Abile/Tau - Ka*Ag)
         sequence{
                 Gbr=0;
                 sleep(Tbeginbump);
                 Gbr=1;
                 sleep(Tau);
                 Gbr=0;
         }
         C = A1/Vc
         Ct = A2/Vt
         dosepoint(A1)
         error(CEps=1)
         observe(CObs = C+CEps)
         stparm(Vc = (tvVc))
         stparm(Cl = (tvCl))
         stparm(Vt = (tvVt))
         stparm(Cld = (tvCld))
         stparm(Ka = tvKa)
         stparm(K1g = tvK1g)
         stparm(Tau = tvTau)
         fixef(tvVc = c(, 13, ))
         fixef(tvCl = c(, 1.2, ))
         fixef(tvVt = c(, 35, ))
         fixef(tvCld = c(, 10, ))
         fixef(tvKa = 2.3)
         fixef(tvK1g = 0.7)
         fixef(tvTau = 2.8)
         covariate(Gbr)
  }
  
  Emily
  
  

  Back to the Top

• On 23 Aug 2011 at 14:04:00, Youssef Hijazi (youssef.hijazi1.-at-.gmail.com) sent the message
  

  
  Dear Zhu,
  
  You can try the below model code I have recently used in in WinNonlin.
  ttom and k1g corrseponds to the bile emptying interval and bile
  excretion rate constant respectively. Details are available in the text
  book of Gabrielsson and Weiner on PKPD analysis.
  
  Kind Regards, Youssef
  
  Youssef Hijazi, PhD. PharmD, member ACCP
  Associate Director Pharmacokinetics
  Micromet AG
  81477 Munich, Germany
  
  Model 1
  remark   ******************************************************
  remark
  remark - define model-specific commands
  COMMANDS
  NFUNCTIONS 1
  NDERIVATIVES 4
  NPARAMETERS 7
  PNAMES  'Vc', 'Vt', 'CL', 'CLd', 'ka', 'k1g', 'ttom'
  END
  remark - define temporary variables
  TEMPORARY
  Dose=CON(1)
  T=X
  RI=8
  END
  remark - define differential equations starting values
  START
  Z(1) = Dose/Vc
  Z(2) = 0
  Z(3) = 0
  Z(4) = 0
  END
  remark - define differential equations
  DIFFERENTIAL
  DZ(1) = (ka*Z(3) - CL*Z(1) - CLd*Z(1) + CLd*Z(2) - k1g*Z(1)*Vc)/Vc
  DZ(2) = (CLd*Z(1) - CLd*Z(2))/Vt
  IF T GE RI AND T LE (RI+ttom) THEN
  DZ(3) = (Z(4)/ttom - ka*Z(3))
  DZ(4) = (k1g*Z(1)*Vc - Z(4)/ttom)
  ELSE
  DZ(3) = (- ka*Z(3))
  DZ(4) = k1g*Z(1)*Vc
  ENDIF
  END
  remark - define algebraic functions
  FUNCTION 1
  F= Z(1)
  END
  remark - define any secondary parameters
  remark - end of model
  EOM
  
  

  Back to the Top

Copyright 1995-2011 David W. A. Bourne (david@boomer.org)